Excel VBA: Unterschied zwischen den Versionen

Aktuelle Version vom 1. Mai 2016, 14:12 Uhr

VBA

• VBA = Visual Basic for Applications
• Basiert auf der objektorientierten Programmiersprache Visual Basic von Windows
• Spezielle Programmiersprache für MS Office
• Automatisierung von Sub-Routinen und Funktionen für Excel, die nach dem Eigenbedarf angepasst werden können
• VBA Code kann Objekte verändern

VBA-Editor

Screenshot des VBA-Editors in Excel unter Windows

Screenshot des VBA-Editors in Excel unter Mac OSX

Der VBA-Editor kann über verschiedene Wege aufgerufen werden. Der schnellste erfolgt jeweils über die Variante mit den Shortcuts, unabhängig vom Betriebssystem.

Shortcuts

Windows:
MS Excel starten » im geöffneten Excel die Tastenkombination "Alt + F11" drücken

Mac:
MS Excel starten » im geöffneten Excel die Tastenkombination "fn + alt + F11" drücken
Problem: In der Office 365 Version wurde der VBA-Editor um einige elementare Funktionen reduziert.
Laut MS soll aber in der Office 2016 Version der VBA-Editor wieder vollständig implementiert sein.

Registerkarte "Entwicklungstools"

Bei sämtlichen Produkten von Office 2010 steht das Register "Entwicklungstools" zur Verfügung. Standardmäßig ist dieses deaktiviert. Um es zu aktivieren, muss man folgende Schritte unternehmen:

Windows:

1. Register "Datei" » Optionen » Dialogfeld "Excel-Optionen" wird geöffnet
2. Auf die linke Seite des Dialogfelds "Menüband anpassen" klicken
3. Auf der rechten Seite des Dialogfelds in der Dropdown-Liste "Befehle auswählen", "Häufig verwendete Befehle" in der Liste auswählen
4. Auf der rechten Seite des Dialogfelds einen Haken bei "Entwicklungstools" setzen.
5. Mit "OK" bestätigen.
   

Mac:

1. Menüleiste "Excel" » Einstellungen ... » Ansicht » Dialogfeld "Ansicht" wird geöffnet
2. Unten im Dialogfeld einen Haken bei "Registerkarte Entwickler" setzen
3. Fenster schließen
   

VBA Programmierungssyntax

Sub-Routinen / Funktionen

Einen VBA-Code den man im VBA-Editor schreibt, bezeichnet man als Prozedur. Gängige Prozeduren hierbei sind "Sub" und "Function". Die meisten Makros die man mit VBA realisiert sind Sub-Prozeduren.

Sub

Eine Gruppe von VBA-Anweisungen, die eine (oder mehrere) Aktionen in Excel durchführen (= Ausführung eines Befehls). Welche Aktion durchgeführt wird, hängt vom programmierten Sub-Code ab.

Die Initialisierung einer Sub-Prozedur erfolgt mit dem Schlagwort "Sub" und endet mit "End Sub". Hier ist ein Codebeispiel:

 Sub TextMitteilung()
 MsgBox “Hallo Welt! Dies ist eine Textmitteilung.”
 End Sub

Function

Eine Gruppe von VBA-Anweisungen, die eine Berechnung anhand übergebener Argumente durchführt und einen einzelnen Wert liefert.

Jede Funktion startet mit dem Schlagwort "Function" und endet mit "End Function".

Wird die Funktion global ("public") deklariert, so kann man diese in der Funktionsleiste von Excel aufrufen, ihr ein oder mehrere Argumente übergeben und Berechnungen durchführen lassen.

Public Function Quadratwurzel(x)
'Abs() liefert den absoluten Werten einer Zahl
xAbs = Abs(x)
Quadratwurzel = xAbs ^ (1 / 3)
End Function

Public Function QuadrFunkt(x, a, b, c)
QuadrFunkt = (a * (x ^ 2)) + b * x + c
End Function

Variablen und Konstanten

Variablen sind Daten, die sich während des Organisationsablauf im Programm verändern können. Diese müssen mit einer zweistufigen Methode zunächst deklariert und anschließend initialisiert werden. Bei Konstanten erfolgt dies mittels einstufiger Methode.

Wichtig hierbei ist, dass VBA zwischen "expliziter" und "impliziter" Variablendeklaration unterscheidet:

• explizite Deklaration: Festlegung der Variable vor ihrem Einsatz
• implizite Deklaration: Variable wird bei ihrer ersten Verwendung in der Prozedur automatisch erzeugt (= fehleranfällig; erschwert das debuggen)
  

Soll eine Variable ihren Wert niemals verändern (bspw. physikalische Größen wie Kelvin, Erdbeschleunigung, o.ä.), nutzt man den Einsatz von Konstanten.

Zur einfachen Handhabung empfiehlt es sich daher, Variablen vor dem Einsatz genau zu definieren:

Um eine Variablendeklaration zu erzwingen, kann man den Befehl Option Explicit in der ersten Zeile am Modulanfang hinzufügen. Der VBA-Code wird solange nicht ausgeführt bzw. gibt einen Fehlermeldung aus, bis alle Variablen korrekt deklariert sind.

Benennung von Parametern

Für die Benennung von Parametern wie bspw. Variablen, Konstanten, Sub und Functions, muss folgendes beachtet werden:

• Sie können aus Buchstaben, Zahlen und einigen Satzzeichen bestehen. Das erste Zeichen muss allerdings aus einem Buchstaben bestehen.
• Es dürfen keine Punkte oder Leerzeichen im Namen verwendet werden.
• Visual Basic for Applications unterscheidet nicht zwischen Groß- und Kleinschreibung.
• Folgende Zeichen können nicht verwendet werden: #, $, %, &, @, ^, *, !
• Wenn eine Function in einem Formular vorgesehen ist, sollte sie nicht wie eine Zelladresse (bspw. AC12) benannt werden. Excel erlaubt zwar diese Benennung, aber man muss sich nicht unnötig verwirren lassen.
• Eine Zeichenkette darf nicht länger als 255 Zeichen lang sein.

Zuweisungen

Wert = 10+11*12/13
Text = “Hallo” & “Welt”

Formula1 := “$C$3”
FileName := ”Exceldateiname.xls"

Set Auswahl = Selection
Set Dok1 = ActiveDocument

Gültigkeitsbereiche von Variablen

Mit dem Schlagwort Dim werden Variablen festgelegt, die nur innerhalb einer Prozedur/Funktion laufen sollen.

Legt man Variablen im Deklarationsteil eines Moduls fest, im Modulkopf, vor der ersten Funktion/Prozedur, so sind diese Variablen global verfügbar.

Durch das Schlagwort Public werden Variablen festgelegt, die über alle Module hinweg verfügbar sein sollen.

Werden Variablen nicht deklariert, so sind diese nur standardmäßig lokal gültig.

Modulkopf

Public Variable As Integer

Dim Variable As Integer

Private Variable As Integer

Prozedur/Funktion

Dim Variable As Integer

Static Variable As Integer

Arrays / Collections

Arrays

Wie bei anderen Programmiersprachen üblich, können Variablen in Form von Feldern, sogenannten Arrays, zusammengefasst werden. Hierbei werden Elemente durch einen fortlaufenden Index unterschieden und angesprochen. Elemente können verschiedene Werte/Datentypen in einem Array speichern (siehe Beispielcode).

Obwohl die Größe des Arrays nachfolgend im Beispiel mit 5 indiziert ist, können 6 Werte im Array gespeichert werden, da ein Array immer bei 0 anfängt. Der Array-Index kann niemals negativ sein.

Deklaration und Aufruf eines Arrays in einer Mitteilungsbox mit Hilfe eines Buttons:

Sub Array_Click()
 Dim BspArray(5) As Variant
 
 BspArray(0) = "21"                  'Zahl als String
 BspArray(1) = 0.25                  'Dezimalzahl
 BspArray(2) = #3/26/2016#           'Datum
 BspArray(3) = #7:20:00 PM#          'Uhrzeit
 BspArray(4) = "BSB"                 'String
 BspArray(5) = 123                   'Zahl
 
'vbCrLf = Zeilenumbruch; "_" erlaubt einen Zeilenumbruch im Code zur besseren Lesbarkeit des Codes
 MsgBox "Element in Array bei index = 0 : " & BspArray(0) & vbCrLf & _
        "Element in Array bei index = 1 : " & BspArray(1) & vbCrLf & _
        "Element in Array bei index = 2 : " & BspArray(2) & vbCrLf & _
        "Element in Array bei index = 3 : " & BspArray(3) & vbCrLf & _
        "Element in Array bei index = 4 : " & BspArray(4) & vbCrLf & _
        "Element in Array bei index = 5 : " & BspArray(5)
End Sub

Die Zuweisung von Werten kann auch innerhalb der Deklarationszeile des Arrays erfolgen

Dim BspArray() As Double = {1.23, 2.34, 3, 4.56, 5}

Mehrdimensionale Arrays

Arrays sind nicht auf eine einfache Dimension limitiert. Das Maximum liegt bei 60 Dimensionen. Zweidimensionale Arrays sind die mit am häufigst verwendeten:

'Mit einem Klick auf einen Button wird die Prozedur gestartet
 Sub MD_Array_Click()
'Das BspArray wird als String deklariert, da es mit Zeichenketten gefüllt wird
  Dim BspArray(2, 3) As String   ' Das BspArray besitzt 3 Zeilen und 4 Spalten
'Das BspArray wird mit Werten gefüllt (siehe obere Grafik)
    BspArray(0, 0) = "Muskat"
    BspArray(0, 1) = "Zimt"
    BspArray(0, 2) = "Borretsch"
    BspArray(0, 3) = "Apfel"
    BspArray(1, 0) = "Orange"
    BspArray(1, 1) = "Kirsche"
    BspArray(1, 2) = "Yuzu"
    BspArray(1, 3) = "Himbeere"
    BspArray(2, 0) = "Tencha"
    BspArray(2, 1) = "Mohn"
    BspArray(2, 2) = "Tonkabohne"
    BspArray(2, 3) = "Thymian"
 
'vbCrLf = Zeilenumbruch; "_" erlaubt einen Zeilenumbruch im Code zur besseren Lesbarkeit des Codes
 MsgBox "Element in Array bei Index = 0,1 : " & BspArray(0, 1) & vbCrLf & _
        "Element in Array bei Index = 2,2 : " & BspArray(2, 2)
 End Sub

Collections

Mit Collections kann man Listen, ähnlich wie Arrays, erstellen.

Das managen dieser Liste erfolgt über die Add(), Remove(), Clear(), Contains() Methode und der Count bzw. Item-Eigenschaft.

Sub Fruit_Collection() 
 Dim colFruit As Collection          'Deklaration der Collection "Fruit"
 Dim colCitrus As Collection         'Deklaration der Collection "Citrus"
 Dim colBanana As Collection         'Deklaration der Collection "Banana"
    
 Set colFruit = New Collection       'Erzeugung der Collection, damit man mit ihr arbeiten kann
 Set colCitrus = New Collection    
 Set colBanana = New Collection    
 
 With colCitrus                      'Hinzufügen von Daten in die colCitrus-Liste
  .Add "Yuzu", "Art" 
  .Add "Sapindales", "Ordnung" 
  .Add "Rutaceae", "Familie" 
  .Add "Citrus", "Gattung" 
 End With 
 
 colFruit.Add colCitrus              'Die colCitrus-Liste wird der colFruit-Liste hinzugefügt
  
 With colBanana                      'Hinzufügen von Daten in die colBanana-Liste
  .Add "Dessertbanane", "Art" 
  .Add "Zingiberales", "Ordnung" 
  .Add "Musaceae", "Familie" 
  .Add "Bananen", "Gattung" 
 End With 
 colFruit.Add colBanana              'Die colBanana-Liste wird der colFruit-Liste hinzugefügt
End Sub

Konvertierung/Manipulation von Daten

VBA liefert über Hundert Möglichkeiten, Daten zu manipulieren. Die bedeutesten sind hier in einer Tabelle zusammengefasst.

Datentypen

Die Deklaration der Datentypen kann auch in einer verkürzten Form vorgenommen werden. Hierzu verwendet man das jeweilige Symbol des Datentyps. Die Bezeichnung "As Datentyp" entfällt.

Dim Variable As Integer, Variable2 As String, Variable3 As Single

Dim Variable%, Variable2$, Variable3!

Operatoren

Kontrollstrukturen

Wie bei allen gängigen Progammiersprachen üblich, besitzt Visual Basic for Applications ebenfalls eine Auswahl an Kontrollstrukturen. Diese sind nachfolgend tabellarisch aufgelistet.

Bedingungen

If Bedingung_erfuellt 
Then Anweisung1 
Else Anweisung2 
End If

If Bedingung_erfuellt Then Anweisung1 
ElseIf Bedingung_erfuellt Then Anweisung 2
Else Anweisung3 
End If

IIf (Bedingung_erfuellt, Anweisung 1, Anweisung 2)

Select Case Variable 
Case Ausdruck 
  Anweisung1
Case Else Anweisung2
End Select

Switch (Bedingung1, Ausdruck1, Bedingung2, Ausdruck2, ... ,Bedingung_n,Ausdruck_n)

Choose (Index, Ausdruck1, Ausdruck2, ... , Ausdruck_n)

Schleifen

While Bedingung_erfuellt
 Anweisung
End While

Do While Bedingung_erfuellt
 Anweisung
Loop

Do Until Bedingung_erfuellt
 Anweisung
Loop

Do
 Anweisung
Loop While Bedingung_erfuellt

Do
 Anweisung
Loop Until Bedingung_erfuellt

For i = Startwert To Endwert Step Schrittweite
 Anweisung
Next i

For Each Objekt In Auflistung
 Anweisung
Next

With Objekt 
 Anweisung
End With

VBA und Excel

Um Visual Basic for Applications in Excel zu verstehen, ist es wichtig zu erkennen, dass dies eine objektorientierte Programmiersprache ist. Sie besteht aus Objekten, Methoden und Eigenschaften.

Ein VBA Objekt ist etwas, das eine bestimme Funktion, Eigenschaften, Daten oder vererbte Objekte enthält.

Um das besser zu verstehen, nehmen wir uns ein Beispiel aus der realen Welt. Ein Haus zum Beispiel, ist ein Objekt. Fenster, Türen, usw. sind vererbte Objekte des Hauses. Ein Haus hat ein paar Charakteristiken oder Eigenschaften, wie beispielsweise die Farbe, Höhe, Anzahl an Etagen und besitzt ebenso einige Events, wie "Tür öffnen", "Tür schließen", etc.

Vergleichsweise ähnlich verhält es sich mit einem Excel Arbeitsblatt. Dieses ist ein Objekt und eine Reihe oder Zellen des Arbeitsblatts sind die vererbten Objekte von einem Arbeitsblatt. Das Arbeitsblatt besitzt bestimmte Eigenschaften, Methoden und Events.

Excel Objekte

Anbei sind hier die wichtigsten Objekte aufgelistet. Für weitere Objekte bedient man sich der Online verfügbaren Referenz von Objekten auf der Microsoft Developer Network Webseite: Microsoft Developer Network

Excel Methoden

Methoden sind Aktionen, die vom Objekt bzw. vererbten Objekt ausgeführt werden können. Bei dem Beispiel mit dem Haus, wäre eine Methode das Streichen eines Raumes, das Bauen eines neuen Raumes, etc.

Damit man in Excel auf Tabelleninhalte zurückgreifen und diese auch manipulieren kann, muss man diese zunächst deklarieren und anschließend mit der Select Methode auswählen. Möchte man den Inhalt beispielsweise anschließend an eine andere Stelle kopieren, muss man die copy und paste Methoden einsetzen:

Sub RangeMethoden_Click()
'In der Auswahl C3:C7 wird die Auswahl mit dem Wert 123 gefüllt
 Range("C3:C7").Value = 123
'Die Auswahl C3:C7 wird ausgewählt
 Range("C3:E7").Select
'Die festgelegte Auswahl wird kopiert
 Selection.Copy
'Die Auswahl A1:A5 wird ausgewählt
 Range("A1:A5").Select
'Die zuvor kopierten Werte aus C3:C7 werden in A1:A5 eingefügt
 ActiveSheet.Paste
End Sub

Aktionen mit Arbeitsmappen/Tabellenblättern

Zellenbereiche (Zellen/Spalten) verändern

Filterfunktionen

Ein- und Ausgabeanweisungen

Für die Interaktion mit dem Benutzer ist es erforderlich, mit diesem zu kommunizieren. Dies kann zum einen über die Input- bzw. Mitteilungsbox von VBA erfolgen oder über Formularsteuerelemente (siehe unten).

InputBox

Die InputBox ist ein Dialogfeld für die Benutzereingabe, die sämtliche Informationen wiedergibt, die in das Eingabefeld übergeben wurden.

Sie kann sowohl als Funktion, als auch als Methode innerhalb von VBA verwendet werden:

InputBox(Prompt, Title, Default, Left, Top)

Object.InputBox(Prompt, Title, Default, Left, Top, HelpFile, HelpContextID, Type)

Werden nicht alle Parameter benötigt, so können diese mit einem Leerzeichen ausgelassen werden:

Object.InputBox("Mitteilungsaufforderung an den Benutzer", "Eingabeaufforderung", , , , , , 1)

Wenn man nur spezifische Parameter unabhängig von der festgelegten Reihenfolge übergeben bzw. nicht den kompletten Satz an Parametern ausfüllen will, so bedient man sich der Parameterübergabe in Prozeduren ":=":

Object.InputBox(Type:=1, Prompt:="Mitteilungsaufforderung an den Benutzer", Title:="Eingabeaufforderung")

Parameter

	VBA InputBox Video-Tutorial von Andreas Thehos
	https://www.youtube.com/watch?v=-e0IfPyyxck

MsgBox

Die Mitteilungsbox dient der Wiedergabe von einfachen Informationen (Status- oder Warnmeldungen) und Ergebnissen. Des Weiteren stellt diese auch Schaltflächen, sog. Buttons, zur Verfügung, die den weiteren Prozessablauf steuern können.

'Deklaration der MsgBox erfolgt ähnlich wie bei der InputBox
MsgBox(Prompt, Buttons, Title, Helpfile, Context)
 
'Codebeispiel mit alphanumerischen Parametern "Buttons"
MsgBox "Mitteilung", vbYesNoCancel + vbInformation + vbDefaultButton1, "Information"
 
'Codebeispiel mit numerischen Parametern "Buttons"
MsgBox "Mitteilung", 3 + 64 + 0, "Information"

Bei dem Parameter "Buttons" muss entweder eine Zahl oder eine Konstante für die Definition angegeben werden. Eine Kombination erfolgt mit "+". Will man den Wert in einer Variable übergeben lassen, d.h. man will wissen, welchen Button der Benutzer gedrückt hat, so muss man die bei der Deklaration angegeben Klammern setzen:

'Unabhängig davon, wie die Schalfläche deklariert ist (alpha- oder numerisch), liefert die Variable den Wert des jeweils ausgewählten Button
MsgBox_Aktivierte_Schaltflaeche = MsgBox("Mitteilung", 3 + 64 + 0, "Information")

	VBA MsgBox Video-Tutorial von Andreas Thehos
	https://www.youtube.com/watch?v=ssei8pEt2rM

Kombination von Input- und MsgBox

'Prozedur wird mit Klick auf einen Button gestartet
Sub QuadrFunktSub_Click()
'inpt-Variablen und QdrFkt werden als Double Datentyp deklariert
 Dim inptX#, inptA#, inptB#, inptC#, QdrFkt#
'Eingabewerte aus InputBox werden an die inpt-Variablen übergeben
  inptX = Application.InputBox("x", "x Eingabeaufforderung", , , , , , 1)
  inptA = Application.InputBox("a", "a Eingabeaufforderung", , , , , , 1)
  inptB = Application.InputBox("b", "b Eingabeaufforderung", , , , , , 1)
  inptC = Application.InputBox("c", "c Eingabeaufforderung", , , , , , 1)
'Berechnung des Funktionswertes einer quadratischen Funktion aus übermittelten Werten
 QdrFkt = (inptA * (inptX ^ 2)) + inptB * inptX + inptC
'Ausgabe des Funktionswertes in einer MsgBox
 MsgBox "Ermittelter Funktionswert:" & vbCrLf & QdrFkt
End Sub

Formularsteuerelemente / UserForm

Eine Übersicht über die Formularsteuerelemente liefert die folgende Grafik. Die Grün hinterlegten Beschriftungen sind die Objektbezeichnungen in VBA.

Um ein Formularsteuerelement hinzuzufügen, öffnet man den VBA-Editor und klickt auf die mit dem grünen Pfeil markierte Liste und wählt "Userform" aus. Alternativ über "Einfügen" » "UserForm". Es wird nun standardmäßig ein Dialogfeld (UserForm) auf der rechten Seite angezeigt, welches man mit beliebigen Steuerelementen per Drag&Dropfüllen kann. Damit man später im Code besser mit den Steuerelementen arbeiten kann, sollte man mit Präfixen bei der Variablendeklaration arbeiten. Hierzu weist man den Objekten im Eigenschaftenfeld links bei "(Name)" den Präfix plus Variablenname zu. Bei manchen Steuerelementen wie bspw. dem Befehlsbutton, kann man der Schaltfläche einen anzuzeigenden Text übergeben, im Feld "Caption". Wenn man einen Doppelklick im Projektexplorer links auf "Userform" (blauer Pfeil) tätigt, gelangt man stets zur Oberfläche des Formulars zurück.

Die folgende Tabelle liefert gängige Präfixe für die verschiedenen Steuerelemente sowie erläuternde Videotutorials:

Symbol	Steuerelement	Präfix	Beschreibung
	Object	obj	Objekt wählen
	Label	lbl	Beschriftungsfeld
	TextBox	txt	Ein Textfeld, das zur Eingabe von Daten dient
	ComboBox	cbo	Auswahlliste WiseOwlTutorials: https://www.youtube.com/watch?v=wgInu5NO9rY
	ListBox	lst	Ein Listenfeld, dem verschiedene Inhalte übergeben werden können Balders Welt: https://www.youtube.com/watch?v=Cn_uRBUwqRE
	CheckBox	chk	Kontrollkästchen
	OptionButton	opt	Ein Optionsfeld das bspw. eingesetzt wird, um eine Auswahl von mehren Möglichkeiten aus zu wählen. ExcelVbaIsFun: https://www.youtube.com/watch?v=6Ju6B99eleo
	ToggleButton	tgl	Dieses Umschaltfeld dient dazu, um bei einem ersten Click eine Aktion auszuführen und bei einem erneuten Klick auf den Button wird eine zweite Aktion ausgeführt. Todd Grande: https://www.youtube.com/watch?v=DAvZufkW8W0
	Frame	fra	Rahmen (bspw. um Kontrollkästchen/Umschaltfeld) Andreas Thehos: https://www.youtube.com/watch?v=h9TG1_YIbSg
	CommandButton	cmd	Befehlsfläche zum Ausführen von Prozeduren. ExcelVbaIsFun: https://www.youtube.com/watch?v=E6MQddLYX18
	TabStrip	tab	Dialogunterteilung WiseOwlTutorials: https://www.youtube.com/watch?v=488ZD_w-MZE
	MultiPage	mlp	Dialogunterteilung Todd Grande: https://www.youtube.com/watch?v=WwEpYcoDPg0
	Scrollbar	(h/v)sb	Scrollleiste
	SpinButton	spn	Button zum mini-/maximieren von Zahlen. ExcelVbaIsFun: https://www.youtube.com/watch?v=6r4w5LDCgkU
	Image	img	Über das Eigenschaftsfeld kann bei "Picture" ein Bild ausgewählt werden, das im Formular angezeigt werden soll. YourProgrammingNetwork: https://www.youtube.com/watch?v=SpBStlU4LTo
	RefEdit	ref	Dient dazu um eine Range vom User übermittelt zu bekommen. Todd Grande: https://www.youtube.com/watch?v=IFHHQYxR11k

Tätigt man einen Doppelklick auf das einzelne Steuerelementobjekt, so öffnet sich der Editor und man kann dort entsprechende Prozeduren programmieren bzw. hinterlegen. Bei der linken Dropdown-Liste kann man das jeweilige Objekt auswählen, das im Formular vorhanden ist. Die zugehörige rechte Dropdown-Liste liefert das zugehörige Event (bspw. Click(), um bei einem Klick auf einen Button die Prozedur zu starten):

Excel Eigenschaften

Eigenschaften sind die Charakteristiken eines Objektes, die gemessen und quantifiziert werden können. Im Bezug auf das Haus kann das die Breite, die Höhe, die Farbe, etc. sein.

In Excel hat man ebenfalls verschiedene Eigenschaften die gemessen und quantifiziert werden können. Dies wäre z.B. bei einem Range Objekt, die Eigenschaften Value, Font.ColorIndex, Interior.ColorIndex, ...

Farb-Deklaration

Die Deklaration der Farbe kann über verschiedene Wege erfolgen. Es stehen drei Möglichkeiten zur Verfügung:

ColorIndex (abhängig von der Farbpalette in Excel; Index reicht von 1 bis 56):

RGB(r,g,b):
Die zugehörigen Argumente liefert ein Generator: http://www.rapidtables.com/web/color/color-scheme.htm

Integrierte Konstanten zuweisen:
vbBlack, vbRed, vbGreen, vbYellow, vbBlue, vbMagenta, vbCyan, vbWhite

Schrift-Formatierung

Rahmen-Formatierung

Zellen-Formatierung

Formatierungsbeispiel

Sub RangeEigenschaften_Click()
'### S C H R I F T ###
'Der Auswahl A1:C3  in der Tabelle1 wird der Wert 123 in jeder Zelle zugewiesen.
 Worksheets("Tabelle1").Range("A1:C3").Value = 123
 
'Die Schriftfarbe der Zelle C3 in der Tabelle1 mit Weiss anfärben
 Worksheets("Tabelle1").Range("C3").Font.ColorIndex = 2
 
'### R A H M E N ####
'Der Auswahl C6:E8 in der Tabelle1 werden Rahmeneigenschaften zugewiesen
 With Worksheets("Tabelle1").Range("C6:E8").Borders
'Rahmendicke = Dünn
  .Weight = xlThin
'Linienart = gestrichelt
  .LineStyle = xlDash
'Farbe = Marineblau
  .Color = RGB(0, 17, 255)
 End With
 
'### Z E L L E N ###
'Zelle C3 in der Tabelle1 mit Cyan anfärben
 Worksheets("Tabelle1").Range("C3").Interior.ColorIndex = 8
 
'Zelle C3 in der Tabelle1 automatisch in der Breite anpassen
 Worksheets("Tabelle1").Range("C3").Columns.AutoFit
End Sub

Makros

Als Makros bezeichnet man die Prozeduren, die man mit Visual Basic for Applications programmiert (=für Fortgeschrittene).
Für Laien gibt es allerdings die Möglichkeit, Makros mit dem Makro-Recoder in Excel "aufzunehmen". Das häufige Problem bei dieser Methode ist, dass der Code im Backend mit zu viel Code überladen wird, das Arbeitsspeicher kostet.

Makro aufzeichnen

Die Aufzeichnung eines Makros erfolgt über das Register "Entwicklungstools" » Abschnitt "Code" » Makro aufzeichnen:


Es öffnet sich ein Dialogfenster, in dem man die Makrobezeichnung, eine Tastenkombination zum Ausführen der Prozedur (hier empfiehlt es sich mit Strg+Shift+Taste zu arbeiten, da viele Tastenbefehle vom Typ Strg+Taste bereits belegt sind), die Bereitstellung des Makros, als auch eine kurze oder detaillierte Beschreibung über die Funktion des Makros angibt. Abschließend mit "OK" bestätigen:



Anschließend werden sämtliche Aktionen, die in der Arbeitsmappe ausgeführt werden, aufgezeichnet. Die Aufzeichnung wird beendet, indem man auf die selbe Schaltfläche "Aufzeichnung beenden" klickt:

Add-In

Wenn man über "Add-In's" redet, meint man eigentlich Tabellenblatt-Add-ins. Das heisst, dass dem Tabellenblatt etwas hinzugefügt wird, um seine Funktionalität zu erweitern. Microsoft Office beispielsweise liefert Add-Ins in seiner Office-Suite mit. Das meist bekannte ist das "Analyse Funktionen" Add-In, welches statistische und analytische Funktionen hinzufügt, die standardmäßig in Excel nicht implementiert sind.

Add-In aktivieren

Windows:
Möglichkeit a)

• Wenn die Registerkarte "Entwicklertools" aktiviert ist, auf den Button "Add-In" klicken.
  

• Einen Haken bei dem jeweiligen Add-In setzen und mit "OK" bestätigen.
  
  

Möglichkeit b)

• Register "Datei" » Optionen » Dialogfeld "Excel-Optionen" wird geöffnet
• Auf die linke Seite des Dialogfelds "Add-Ins" klicken
• Unten im Dialogfeld, in der Dropdown-Liste "Verwalten", "Excel-Add-Inns" auswählen und auf "Gehe zu..." klicken.
• Gewünschtes Add-In auswählen und mit "OK" bestätigen.

Add-In Eigenschaften & Schutz festlegen

Bevor man das Add-In zur Verfügung stellt, kann man diesem einen Titel und eine Beschreibung hinzufügen. Dies geschieht im VBA Editor » Extras » Eigenschaften von Projekt » Reiter "Allgemein":



Möchte man das Add-In schützen, so kann man dieses zum einen sperren und zum anderen ein Passwort festlegen, in dem selben Dialogfeld, im Reiter "Schutz":

Add-In zur Verfügung stellen

Um Excelprozeduren für eine breite Masse an Benutzer zur Verfügung zu stellen, empfiehlt es sich, Sub-Prozeduren und Funktionen als Add-In zur Verfügung zu stellen.

Hierzu geht man auf das Register "Datei" » Speichern unter » und wählt in dem sich öffnenden Dialogfeld beim Dateityp "Excel Add-In" aus, wählt einen Speicherort aus und bestätigt mit "speichern":

Das nun erzeugte Add-In kann man über das Register "Entwicklungstools" » Add-Ins » Durchsuchen ... » auswählen » bestätigen und anschließend im Dialogfeld einen Haken setzen, damit dieses aktiviert ist » mit "OK" bestätigen.

WICHTIG: Zum ändern von Add-Ins benötigt man immer die Original Excelmappe, in der die Makros verankert sind. Denn Add-Ins kann man nicht mehr im Nachhinein ändern!

Bibliographie

Die hier aufgeführten Informationen und Codeausschnitte zu diversen Anwendungsfällen wurden den unten aufgeführten Quellen entnommen oder angelehnt und dem Wikiverlauf entsprechend zusammengestellt.

Literaturverzeichnis

Abulawi, J. (2005): "Einführung in die Excel-Makroprogrammierung", unter https://www.haw-hamburg.de/pers/Abulawi/ExcelmakrosSS05.pdf (abgerufen am 18.03.2016).

Bürschgens, M. (2011): "Einstieg in VBA und die Officeprogrammierung am Beispiel von Excel", unter https://www.matse.itc.rwth-aachen.de/dienste/public/show_document.php?id=7946 (abgerufen am 18.03.2016).

Friedrich, S., Klein, A. (2005): "Excel 2003 Progammierung mit Visual Basic", unter http://www.merkwerk.de/files/exvba.pdf (abgerufen am 18.03.2016)

Gogolok, J. (1999): "VBA-Programmierung mit Excel", unter ftp://ftp.fernuni-hagen.de/pub/pdf/urz-broschueren/broschueren/b012.pdf (abgerufen am 18.03.2016).

Kämper, S. (2009): Grundkurs Programmieren mit Visual Basic, Wiesbaden, Vieweg+Teubner.

Shichang, W., Schmidt, W. (2015): Berechnungen in der Chemie und Verfahrenstechnik mit Excel und VBA, Weinheim, Wiley-VCH.

Weber, M. (2008): "Eigene Funktionen programmieren", unter http://www.edv-buchversand.de/?cnt=getchapter&id=ms-5209.pdf (abgerufen am 02.04.2016).

Internetverzeichnis

o.A. (2010): "Datensammlung - Arrays und Collections", unter http://www.office-loesung.de/ftopic429248_0_0_asc.php (abgerufen am 28.03.2016)

o.A. (o.J.): „MS Excel: How to use the convert function“, unter: http://www.techonthenet.com/excel/formulas/convert.php (abgerufen am 31.03.2016).

o.A. (o.J.): „Objektmodell (VBA-Referenz für Excel)“, unter: https://msdn.microsoft.com/de-de/library/office/ff194068.aspx (abgerufen am 26.03.2016).

o.A. (o.J.): „Range.Sort-Methode (Excel)“, unter: https://msdn.microsoft.com/de-de/library/office/ff840646.aspx (abgerufen am 31.03.2016).

o.A. (o.J.): „Schnellstart: Aktivieren und Verwenden eines Add-Ins“, unter: https://support.office.com/de-de/article/Schnellstart-Aktivieren-und-Verwenden-eines-Add-Ins-2df59054-a46f-4fe4-bcb5-92ea461c315f (abgerufen am 25.03.2016).

o.A. (o.J.): „VBA Tutorial“, unter: http://www.tutorialspoint.com/vba/ (abgerufen am 26.03.2016).

Chinowsky, B. (2009): „Erste Schritte mit VBA in Excel 2010“, unter: https://msdn.microsoft.com/de-de/library/office/ee814737(v=office.14).aspx (abgerufen am 25.03.2016).

Sens, G.-M. (2016): "Microsoft Office Excel - Fortgeschrittene", unter http://www.staff.uni-giessen.de/~g021/excel_fortgeschrittene.htm (abgerufen am 29.03.2016).